ビルドを理解し、
設計し、改善する。

println("[init] settings")

println '[init] settings'

println("[config] root build")
tasks.register("observe") {
    println("[config] observe")
    doLast { println("[execute] observe") }
}

println '[config] root build'
tasks.register('observe') {
    println '[config] observe'
    doLast { println '[execute] observe' }
}

.\gradlew.bat help --no-configuration-cache
.\gradlew.bat observe --no-configuration-cache

val looseFile = layout.buildDirectory.file("info/loose.txt")
tasks.register("writeLoose") {
    doLast {
        val file = looseFile.get().asFile
        file.parentFile.mkdirs()
        file.writeText("message=hello\n", Charsets.UTF_8)
    }
}

def looseFile = layout.buildDirectory.file('info/loose.txt')
tasks.register('writeLoose') {
    doLast {
        def file = looseFile.get().asFile
        file.parentFile.mkdirs()
        file.setText('message=hello\n', 'UTF-8')
    }
}

.\gradlew.bat writeLoose --no-configuration-cache
.\gradlew.bat writeLoose --no-configuration-cache

import org.gradle.api.DefaultTask
import org.gradle.api.file.RegularFileProperty
import org.gradle.api.provider.Property
import org.gradle.api.tasks.Input
import org.gradle.api.tasks.OutputFile
import org.gradle.api.tasks.TaskAction

abstract class GenerateInfo : DefaultTask() {
    @get:Input
    abstract val message: Property<String>

    @get:OutputFile
    abstract val outputFile: RegularFileProperty

    @TaskAction
    fun generate() {
        val file = outputFile.get().asFile
        file.parentFile.mkdirs()
        file.writeText("message=" + message.get() + "\n", Charsets.UTF_8)
    }
}

val generateInfo = tasks.register<GenerateInfo>("generateInfo") {
    message.set(providers.gradleProperty("message").orElse("hello"))
    outputFile.set(layout.buildDirectory.file("info/build-info.properties"))
}
tasks.register("prepareInfo") {
    dependsOn(generateInfo)
    doLast { println("Info is ready.") }
}

import org.gradle.api.DefaultTask
import org.gradle.api.file.RegularFileProperty
import org.gradle.api.provider.Property
import org.gradle.api.tasks.Input
import org.gradle.api.tasks.OutputFile
import org.gradle.api.tasks.TaskAction

abstract class GenerateInfo extends DefaultTask {
    @Input
    abstract Property<String> getMessage()

    @OutputFile
    abstract RegularFileProperty getOutputFile()

    @TaskAction
    void generate() {
        def file = outputFile.get().asFile
        file.parentFile.mkdirs()
        file.setText('message=' + message.get() + '\n', 'UTF-8')
    }
}

def generateInfo = tasks.register('generateInfo', GenerateInfo) {
    message.set(providers.gradleProperty('message').orElse('hello'))
    outputFile.set(layout.buildDirectory.file('info/build-info.properties'))
}
tasks.register('prepareInfo') {
    dependsOn(generateInfo)
    doLast { println 'Info is ready.' }
}

.\gradlew.bat prepareInfo --no-configuration-cache
.\gradlew.bat prepareInfo --no-configuration-cache
.\gradlew.bat generateInfo -Pmessage=team --no-configuration-cache
Get-Content .\build\info\build-info.properties

Remove-Item -LiteralPath '.\build\info\build-info.properties'
.\gradlew.bat generateInfo -Pmessage=team --no-configuration-cache

[versions]
commons-lang = "3.20.0"
junit = "5.13.4"
versions-plugin = "0.53.0"

[libraries]
commons-lang = { module = "org.apache.commons:commons-lang3", version.ref = "commons-lang" }
junit-bom = { module = "org.junit:junit-bom", version.ref = "junit" }
junit-jupiter = { module = "org.junit.jupiter:junit-jupiter" }
junit-launcher = { module = "org.junit.platform:junit-platform-launcher" }

[plugins]
versions = { id = "com.github.ben-manes.versions", version.ref = "versions-plugin" }

dependencies {
    implementation(project(":common"))
    testImplementation(platform(libs.junit.bom))
    testImplementation(libs.junit.jupiter)
    testRuntimeOnly(libs.junit.launcher)
}

dependencies {
    implementation project(':common')
    testImplementation platform(libs.junit.bom)
    testImplementation libs.junit.jupiter
    testRuntimeOnly libs.junit.launcher
}

dependencies {
    implementation(libs.commons.lang)
}

dependencies {
    implementation libs.commons.lang
}

.\gradlew.bat :app:build --no-configuration-cache
.\gradlew.bat :common:dependencies --configuration runtimeClasspath --no-configuration-cache

pluginManagement {
    includeBuild("build-logic")
}
rootProject.name = "AdvancedSampleSystem"
include("app", "common")

pluginManagement {
    includeBuild 'build-logic'
}
rootProject.name = 'AdvancedSampleSystem'
include 'app', 'common'

rootProject.name = "build-logic"

rootProject.name = 'build-logic'

plugins { id("java-gradle-plugin") }
java { toolchain { languageVersion = JavaLanguageVersion.of(25) } }
gradlePlugin {
    plugins {
        create("javaConventions") {
            id = "guide.java-conventions"
            implementationClass = "guide.JavaConventionsPlugin"
        }
    }
}

plugins { id 'java-gradle-plugin' }
java { toolchain { languageVersion = JavaLanguageVersion.of(25) } }
gradlePlugin {
    plugins {
        javaConventions {
            id = 'guide.java-conventions'
            implementationClass = 'guide.JavaConventionsPlugin'
        }
    }
}

package guide;

import org.gradle.api.Plugin;
import org.gradle.api.Project;
import org.gradle.api.plugins.JavaPluginExtension;
import org.gradle.api.tasks.compile.JavaCompile;
import org.gradle.api.tasks.testing.Test;
import org.gradle.jvm.toolchain.JavaLanguageVersion;

public class JavaConventionsPlugin implements Plugin<Project> {
    @Override
    public void apply(Project project) {
        project.getPluginManager().apply("java");
        project.getRepositories().mavenCentral();
        project.getExtensions().getByType(JavaPluginExtension.class)
            .getToolchain().getLanguageVersion()
            .set(JavaLanguageVersion.of(25));
        project.getTasks().withType(Test.class)
            .configureEach(test -> test.useJUnitPlatform());
        project.getTasks().withType(JavaCompile.class)
            .configureEach(task -> task.getOptions().setEncoding("UTF-8"));
    }
}

plugins {
    application
    id("guide.java-conventions")
}
version = "1.0"
application { mainClass = "guide.Greeting" }

dependencies {
    implementation(project(":common"))
    testImplementation(platform(libs.junit.bom))
    testImplementation(libs.junit.jupiter)
    testRuntimeOnly(libs.junit.launcher)
}

plugins {
    id 'application'
    id 'guide.java-conventions'
}
version = '1.0'
application { mainClass = 'guide.Greeting' }

dependencies {
    implementation project(':common')
    testImplementation platform(libs.junit.bom)
    testImplementation libs.junit.jupiter
    testRuntimeOnly libs.junit.launcher
}

plugins {
    id("java-library")
    id("guide.java-conventions")
}
dependencies {
    implementation(libs.commons.lang)
}

plugins {
    id 'java-library'
    id 'guide.java-conventions'
}
dependencies {
    implementation libs.commons.lang
}

.\gradlew.bat :app:build :app:run --no-configuration-cache

.\gradlew.bat build --no-configuration-cache --no-build-cache
.\gradlew.bat build --no-configuration-cache --no-build-cache

@org.gradle.api.tasks.CacheableTask
abstract class GenerateInfo : DefaultTask() {

@org.gradle.api.tasks.CacheableTask
abstract class GenerateInfo extends DefaultTask {

.\gradlew.bat generateInfo -Pmessage=cache --build-cache --no-configuration-cache
Remove-Item -LiteralPath ".\build\info\build-info.properties"
.\gradlew.bat generateInfo -Pmessage=cache --build-cache --no-configuration-cache

.\gradlew.bat build generateInfo --configuration-cache --build-cache
.\gradlew.bat build generateInfo --configuration-cache --build-cache

.\gradlew.bat --status

.\gradlew.bat projects --no-configuration-cache
.\gradlew.bat -p build-logic tasks --all --no-configuration-cache
.\gradlew.bat :build-logic:build --no-configuration-cache

Set-Location 'C:\自分の練習用フォルダー\AdvancedSampleSystemUpgrade'
Get-Location
.\gradlew.bat --version
.\gradlew.bat build --warning-mode=all --no-configuration-cache

.\gradlew.bat wrapper --gradle-version 9.8.1 --distribution-type bin --no-configuration-cache
.\gradlew.bat wrapper --no-configuration-cache

.\gradlew.bat --version
.\gradlew.bat clean build --warning-mode=all --no-configuration-cache
.\gradlew.bat build generateInfo --configuration-cache
.\gradlew.bat build generateInfo --configuration-cache

Set-Location '..\AdvancedSampleSystem'
Get-Location
.\gradlew.bat --version

plugins {
    id("java-library")
    id("guide.java-conventions")
    id("maven-publish")
}

plugins {
    id 'java-library'
    id 'guide.java-conventions'
    id 'maven-publish'
}

group = "guide.demo"
version = "1.0"

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            from(components["java"])
        }
    }
    repositories {
        maven {
            name = "practice"
            url = uri(layout.projectDirectory.dir("../practice-repo"))
        }
    }
}

group = 'guide.demo'
version = '1.0'

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            name = 'practice'
            url = uri(layout.projectDirectory.dir('../practice-repo'))
        }
    }
}

.\gradlew.bat clean build --no-daemon --no-configuration-cache
if ($LASTEXITCODE -ne 0) { throw "Build failed; stop before publish." }

.\gradlew.bat :common:publishMavenJavaPublicationToPracticeRepository
if ($LASTEXITCODE -ne 0) { throw "Publish failed." }
Get-ChildItem .\practice-repo\guide\demo\common\1.0\